esp32同士でシリアル無線通信をして，無線Lチカ・光量制御をしてみる（Arduino IDE使用）

void setup(void) {
  Serial.begin(115200);
  Serial.println("-----------------");
  uint8_t macBT[6];
  esp_read_mac(macBT, ESP_MAC_BT);
  Serial.printf("%02X:%02X:%02X:%02X:%02X:%02X\r\n", macBT[0], macBT[1], macBT[2], macBT[3], macBT[4], macBT[5]);
}

void loop() {
  delay(1000);
}

#include "BluetoothSerial.h"

BluetoothSerial SerialBT;

String MACadd = "24:62:AB:DC:30:5E";
uint8_t address[6]  = {0x24, 0x62, 0xAB, 0xDC, 0x30, 0x5E};
bool connected;

void setup() {
  Serial.begin(115200);
  SerialBT.begin("ESP32test", true); 
  Serial.println("The device started in master mode, make sure remote BT device is on!");
  
  // connect(address) is fast (upto 10 secs max), connect(name) is slow (upto 30 secs max) as it needs
  // to resolve name to address first, but it allows to connect to different devices with the same name.
  // Set CoreDebugLevel to Info to view devices bluetooth address and device names
  connected = SerialBT.connect(address);
  
  if(connected) {
    Serial.println("Connected Succesfully!");
  } else {
    while(!SerialBT.connected(10000)) {
      Serial.println("Failed to connect. Make sure remote device is available and in range, then restart app."); 
    }
  }
  // disconnect() may take upto 10 secs max
  if (SerialBT.disconnect()) {
    Serial.println("Disconnected Succesfully!");
  }
  // this would reconnect to the name(will use address, if resolved) or address used with connect(name/address).
  SerialBT.connect();

  pinMode( 2, OUTPUT);
  pinMode(14, INPUT_PULLUP);

  // Sign for the end of bluetooth setup.
  for (int i=0; i<3; i++) {
    digitalWrite(2, HIGH);
    delay(50);
    digitalWrite(2, LOW);
    delay(50);
  }
}

void loop() {
  if (digitalRead(14) == LOW) {
    Serial.println("LED is ON.");
    SerialBT.write('T');
  }
  delay(20);
}

#include "BluetoothSerial.h"

#if !defined(CONFIG_BT_ENABLED) || !defined(CONFIG_BLUEDROID_ENABLED)
#error Bluetooth is not enabled! Please run `make menuconfig` to and enable it
#endif

BluetoothSerial SerialBT;

void setup() {
  Serial.begin(115200);
  SerialBT.begin("ESP32test"); //Bluetooth device name
  Serial.println("The device started, now you can pair it with bluetooth!");
  pinMode( 2, OUTPUT);
  pinMode(14, OUTPUT);

  // Sign for the end of bluetooth setup.
  for (int i=0; i<3; i++) {
    digitalWrite(2, HIGH);
    delay(50);
    digitalWrite(2, LOW);
    delay(50);
  }
}

void loop() {
  if (SerialBT.available()) {
    if (SerialBT.read() == 'T') {
        digitalWrite(14, HIGH);
    }
  }
  delay(20);
  digitalWrite(14, LOW);
}

#include "BluetoothSerial.h"
#define BUILTIN_LED 2
#define LEFT_X_PIN 12
#define LEFT_Y_PIN 13

BluetoothSerial SerialBT;

String MACadd = "24:62:AB:DC:30:5E";
uint8_t address[6]  = {0x24, 0x62, 0xAB, 0xDC, 0x30, 0x5E};
bool connected;

void setup() {
  Serial.begin(115200);
  SerialBT.begin("ESP32test", true); 
  Serial.println("The device started in master mode, make sure remote BT device is on!");
  
  // connect(address) is fast (upto 10 secs max), connect(name) is slow (upto 30 secs max) as it needs
  // to resolve name to address first, but it allows to connect to different devices with the same name.
  // Set CoreDebugLevel to Info to view devices bluetooth address and device names
  connected = SerialBT.connect(address);
  
  if(connected) {
    Serial.println("Connected Succesfully!");
  } else {
    while(!SerialBT.connected(10000)) {
      Serial.println("Failed to connect. Make sure remote device is available and in range, then restart app."); 
    }
  }
  // disconnect() may take upto 10 secs max
  if (SerialBT.disconnect()) {
    Serial.println("Disconnected Succesfully!");
  }
  // this would reconnect to the name(will use address, if resolved) or address used with connect(name/address).
  SerialBT.connect();

  pinMode(BUILTIN_LED, OUTPUT);

  // Sign for the end of bluetooth setup.
  for (int i=0; i<3; i++) {
    digitalWrite(BUILTIN_LED, HIGH);
    delay(50);
    digitalWrite(BUILTIN_LED, LOW);
    delay(50);
  }
}

uint8_t calculate_checksum(uint8_t *data) {
  uint8_t checksum = 0;
  checksum |= 0b11110000 & data[1];
  checksum |= 0b00001111 & data[2];

  return checksum;
}

void loop() {
  int left_x_val = 0;
  int left_y_val = 0;
  uint8_t send_data[4];
  
  left_x_val  = analogRead (LEFT_X_PIN) >> 4;
  //Serial.print("X-axis: ");
  //Serial.println(left_x_val);
  
  left_y_val  = analogRead (LEFT_Y_PIN) >> 4;
  //Serial.print("Y-axis: ");
  //Serial.println(left_y_val);

  send_data[0] = 'T';
  send_data[1] = left_x_val;
  send_data[2] = left_y_val;
  send_data[3] = calculate_checksum(send_data);
  SerialBT.write(send_data, 4);

  delay(20);
}

#include "BluetoothSerial.h"

#if !defined(CONFIG_BT_ENABLED) || !defined(CONFIG_BLUEDROID_ENABLED)
#error Bluetooth is not enabled! Please run `make menuconfig` to and enable it
#endif

BluetoothSerial SerialBT;

#define BUILTIN_LED 2
#define LED_PIN_GR 14
#define LED_PIN_BL 15

void setup() {
  Serial.begin(115200);
  SerialBT.begin("ESP32test"); //Bluetooth device name
  Serial.println("The device started, now you can pair it with bluetooth!");
  
  pinMode(BUILTIN_LED, OUTPUT);
  pinMode(LED_PIN_GR, OUTPUT);
  pinMode(LED_PIN_BL, OUTPUT);

  // Sign for the end of bluetooth setup.
  for (int i=0; i<3; i++) {
    digitalWrite(BUILTIN_LED, HIGH);
    delay(50);
    digitalWrite(BUILTIN_LED, LOW);
    delay(50);
  }

  ledcSetup(0,12800,8);
  ledcAttachPin(LED_PIN_GR, 0);
  ledcSetup(1,12800,8);
  ledcAttachPin(LED_PIN_BL, 1);
}

uint8_t calculate_checksum(uint8_t *data) {
  uint8_t checksum = 0;
  checksum |= 0b11110000 & data[1];
  checksum |= 0b00001111 & data[2];

  return checksum;
}

void led_control(uint8_t *data) {
  ledcWrite(0, data[1]);
  ledcWrite(1, data[2]);
}

void data_decode() {
  uint8_t recv_data[4];
  if (SerialBT.available()) {
    SerialBT.readBytes(recv_data, 4);
    
    if (recv_data[0] != 'T') {
      Serial.print("Receive error!");
      return;
    }

    if (recv_data[3] != calculate_checksum(recv_data)) {
      Serial.print("Decode error!");
      return;
    }
    
    led_control(recv_data);
  }
  
  return;
}

void loop() {
  data_decode();
  delay(20);
}